Auto Rally

Play online
It is necessary to enable turbo mode.
The game is in the program cell 0.

Not bad and quite difficult racing with obstacles for MK-85. They require a good, quick reaction from the player. Otherwise, you won't be able to travel the road full of dangers in a racing car!
Written by Andrei (YouTube).

How to play:

Game code (TXT file):

> Game start screen.

1 CSR ,11:PRINT " Auto Rally ";:GOSUB 39:Y=11:GOSUB 38

> VARIABLES: A$(0-3) - road terrain, E$(0-3) - car and route, $ - encoding of the route terrain, K - vehicle position, J$ and Q$ - to save memory.

2 VAC:A$="ELRLRLE":B$="ALA000L":C$="LA000AL"
           A0                      A1                      A2
3 D$="L000ALA":E$="ELRERLE":F$="ALARERL":G$="LARERAL"
   A3                      E0                      E1                      E2
4 H$="LRERALA":$="2222222222":K=2:J$=CHR 96:Q$="0123"
   E3

> Trip counter. W - interval for drawing the middle of the road.

5 W=W+1:N=N+.1:IF N=26 THEN 20
6 CSR 9:PRINT INT N;:CSR 9:LETC "LALALAL":PRINT J$;

> Random number generator for arranging the relief of the route Y$, X$; arrangement, gluing of the route relief encoding in the $ variable for its subsequent display, conditional transition in case of loss.

7 IF W=2;W=0:X$="2":GOTO 10
8 X$=GETC(Q$,4*RAN#+1)
9 IF N>=24;X$="2"
10 $=X$+MID(1,9):IF K<>VAL MID(9,1) THEN 17

> Displays the terrain of the route and the car passing it. Z$=KEY-Joystick, for driving a car.

11 CSR 8:LETC E$(K):PRINT J$;:IF K=0;K=2
12 FOR Y=7 TO 0 STEP -1:Z$=KEY:X=1↑2:IF Z$="W";K=0
13 IF Z$="8";K=K+1
14 IF Z$="5";K=K-1
15 CSR Y:LETC A$(VAL MID(Y+1,1)):PRINT J$;:NEXT Y
16 GOTO 5

> Screen in case of loss.

17 FOR Y=1 TO 5:CSR 8:PRINT " ";:X=2↑2
18 CSR 8:LETC E$(VAL MID(10,1)):PRINT J$;:X=2↑2:NEXT Y
19 CSR ,2:PRINT "НеудачА! ";:GOSUB 39:Y=10:GOSUB 38:GOTO 35

> Screen in case of passing the game, final. A$, B$, C$, D$ - car graphics.

20 CSR ,11:PRINT " ";:GOSUB 39:A$="000133":B$="01FVVJC"
21 C$="V44VVV0":D$="GSVV32S":FOR I=0 TO 3
22 LETC A$(I):PRINT J$;:NEXT I:Y=7:GOSUB 38
23 FOR I=11 TO 6 STEP -1:CSR I,:LETC "046T4AP":PRINT J$;
24 X=2↑2:CSR I,:LETC "08CS88O":PRINT J$;:X=2↑2:NEXT I
25 FOR I=10 TO 8 STEP -2:CSR I,:LETC A$="0FVE44A":PRINT J$;
26 LETC "084S4AP":PRINT J$;:X=2↑3:CSR I-1,:LETC A$:PRINT J$;
27 LETC "084S44C":PRINT J$;:X=2↑3:NEXT I
28 FOR I=4 TO 5:CSR I:LETC "04CN4AJ":PRINT J$;:X=2↑2
29 CSR I:LETC "0267223":PRINT J$;:X=2↑2:CSR I:PRINT " ";
30 NEXT I:CSR 5:LETC "0123223":PRINT J$;:LETC "0G8O88O"
31 PRINT J$;:X=99↑99:CSR 5:LETC A$="04EL4AR":PRINT J$;
32 LETC A$:PRINT J$;:X=99↑99:CSR 6:LETC "0KE54AR":PRINT J$;
33 FOR I=0 TO 20:CSR 5:LETC "0LU44AR":PRINT J$;:X=2↑2:CSR 5
34 LETC "GLE44AR":PRINT J$;:X=2↑2:NEXT I:Y=10:CSR 10:GOSUB 38

> Request to replay or exit the game.

35 CSR 0,:PRINT "Ещё? D/N";
36 $=KEY:IF $="D" THEN 2:IF $="N";CSR 0,:PRINT "";:END
37 GOTO 36

> Subroutine cycles: - gradual shift of the image on the screen, and delay of the image on the screen.

38 FOR Z=0 TO Y:PRINT " ";:X=1↑2:NEXT Z:RETURN
39 FOR X=0 TO 300:NEXT X:RETURN

* THE GAME TAKES 1167 PROGRAM STEPS

===============================================================
* IN ORDER FOR THE CAR TO BE CONTROLLED BY THE MK-85M MICROCOMPUTER ITSELF, YOU NEED TO ADD THE COMMAND TO THE PROGRAM LINE:

16 K=VAL MID(8,1):GOTO 5

===============================================================

The game speed is controlled by the expression X=*↑* in line 12.

===============================================================

Video: