:: Home bs0dd.net :: News :: Guest book ::
:: Nokia Phones FAN-Site :: Nokia 92xx Archive :: Kannel for Windows ::
-- Переключиться на Русский --

Fight!

< Games Main page

Play online
The game is in the program cell 0.

Owners of Siemens phones (more precisely, the C45 and ME45 models) probably remember the game BattleMail well.
This is one of the first network (via SMS) games for mobile phones. You need to specify 6 moves for attack and defense in advance, after which the fight begins. Each player has 5 lives, i.e. can withstand 4 hits and will die after the fifth. If no one dies during the fight, the winner is the one with more lives left. If this indicator is equal, a draw is declared. The concept of the game is simple but interesting, however, due to the need for the operator to support some "special" SMS (if I'm not mistaken), the game did not gain much popularity. So most people only played "training" against the computer, like me.

Actually, this BASIC game is a kind of backport of BattleMail for MK85. The rules of the game are absolutely the same, the battle is conducted with the "computer", which chooses its moves with the help of pseudo generator.

How to play:

Before the game starts, you need to set 6 moves for attack (Atk:) and the same number for defense (Def:).
Strikes and defense can be placed in 3 positions: up (head), forward (stomach) and down (legs).
Directions are indicated by arrows.

Fight img3

Keys:
4 - position up ↑
5 - position down ↓
6 - position forward →
DEL - delete current position
EXE - accept

After this, the microcomputer will "think" for a short time (the computer's moves are generated).
Then the opponent people will appear on the screen, and at the edges of their health bars (each with 5 hits).
The fight will begin. The first player always goes. The screen shows the direction (who hits) and the position of the hit.
If a hit is dealt, █ is displayed instead of the man and the health bar decreases by one unit.
If the position of the strike of the attacker coincides with the position of defense of the opponent, it means that the opponent has set up a block.
Then instead of the man, an X is displayed and the health bar does not decrease.
The game continues until one of the opponents dies or runs out of moves.
If after 6 turns no one has died, then victory is awarded to the player with the most health.
If the amount of health is the same, a draw is declared.

Game code (TXT file):

1 CSR 11:PRINT " Fight! ";:X=4↑.5
2 Y$="EHLVLHV":T$="4A4V4AH":H$="EVVVVVE":E=94:F=24:G=26:M=5:J=5
3 CSR 0,:PRINT "Atk:";:GOSUB 20:A$=$:PRINT "Def:";:GOSUB 20:B$=$
4 N$=H$:C$="":D$="":FOR I=0 TO 5:C$=C$+CHR E(RAN#*3)
5 D$=D$+CHR E(RAN#*3):NEXT I:LETC H$:Q$=CHR 96:PRINT Q$;:CSR 11
6 PRINT Q$;:LETC T$:CSR 3:PRINT Q$;:CSR 8:PRINT Q$;:X=2^2:FOR I=1 TO 6
7 U$=GETC (A$,I):CSR 5:PRINT "-";:W$="X":IF U$!=GETC (D$,I);GOSUB 30
8 PRINT U$;:CSR 8:PRINT W$;:X=2^2:CSR 8:PRINT Q$;:LETC N$:CSR 11
9 PRINT Q$;:LETC T$:IF J=0;CSR 8:LETC Y$:PRINT Q$;:X=4^.5:GOTO 40
10 U$=GETC (C$,I):W$="X":CSR 6:PRINT "-";:IF U$!=GETC (B$,I);GOSUB 31
11 IF U$="→";U$="←"
12 CSR 5:PRINT U$;:CSR 3:PRINT W$;:X=2^2:CSR 3
13 PRINT Q$;:LETC H$:CSR 0:PRINT Q$;:LETC T$
14 IF M=0;CSR 3:LETC Y$:PRINT Q$;:X=4^.5:GOTO 41
15 NEXT I:X=4^.5:IF J=M THEN 42:IF J>M THEN 41:GOTO 40
20 P=0:$=""
21 K=ASCI KEY:IF K=0 THEN 21:IF K=8 THEN 24:IF K=4 THEN 23:IF P=6 THEN 21
22 K=K-52:IF K>=0;IF K<=2;P=P+1:$=$+CHR E(K):GOTO 25
23 P=P+1:IF P=7;CSR 0,:RETURN
24 IF P>0;P=P-1:$=MID (1,P)
25 CSR 5,:PRINT $;:GOTO 21
30 W$="█":J=J-1:$=N$:N$=MID (1,5-J)+"H"+MID (7-J,J+1):RETURN
31 W$="█":M=M-1:$=H$:H$=MID (1,5-M)+"H"+MID (7-M,M+1):RETURN
40 $="Yeeaah":GOTO 43
41 $="So sad":GOTO 43
42 $="Draw."
43 CSR 0,:CSR 3:PRINT $;

The notation != corresponds to the symbol ≠ in MK.
In the title string, there is one space before the word "Fight!" and three spaces after the word.
The symbol █ (there is only one) corresponds to the same symbol in MK (EXT mode, combination S + Z)
If the game is running too fast, you can adjust its speed by changing the "load" expression X=2^2