For MK-85 users !!!!
                             "Tetris" game
                Author: Sergey Bogdanov (fiks), 2000
               Edited by: Bs0Dd, 2023, [mk.bs0dd.net]
    Original taken from the site: http://www.aha.ru/~fiks/tetris/

BEFORE you start entering the code, you must fill in cells
Z$(10)-Z$(24) with codes for the addresses of subroutines
executed in a certain sequence depending on the figure number.

To do this, you need to use an auxiliary mini-program:

1 DEFM24:FORC=10TO24:Z$(C)="":FORI=1TO7:PRINT"C";C-9;" —";I;
2 INPUTV:Z$(C)=Z$(C)+CHRV:NEXTI:NEXTC

The program will request numbers from this table (indicating the
line and number of the number from the table) - enter them one
by one:

154 185 169  75  87 184 184
168  37 184 184 184 184 184
183 154 139  38  25  83 187
183 154  26 169  37  26 188
158  88 188 184 184 184 184
168 184 184 184 184 184 184
168 168 184 184 184 184 184
185 164  33 159  22  58  38
183 154 182 169  38  25  87
154 183 169  28  58  37 184
 53 164 182 159  35  82 188
168  33 187 184 184 184 184
183 154 182 163 118  82  58
154 186 169  76 188 184 184
168  78 184 184 184 184 184

After entering the last number, the program will automatically
end.

If you have a regular MK-85, you need to erase this program,
otherwise there will not be enough space for the game (the game
takes up step 1196 out of 1221).

Please note that if you erase (either intentionally or through
negligence) data cells, you will have to enter them again,
erasing the mini-program portion of the game (266 steps
required).

Now enter the code for the game itself:
                              
1 DEFM 9:VAC:G=1111111:GOTO 50
2 E=E-2
3 E=E+1:RETURN
4 B=C:RETURN
5 F=2:RETURN
6 F=3:RETURN
7 F=1
8 C=C+1:FOR D=E TO E+F-1:G(C)=G(C)+10^D:NEXT D:RETURN
9 IF C<B+1;C=B+1
10 C=C-1:RETURN
11 IF C<B+2;C=B+2
12 C=C-2:RETURN
13 GOSUB 2:GOTO 16
15 F=1
16 FOR C=24 TO 0 STEP -1:IF G(C)=0;NEXT C
17 IF FRAC(INT(G(C)/10^E)/10^F)=0;GOSUB 10:GOTO 17
18 RETURN
50 A=INT(RAN#*15+1):GOSUB 98:FOR B=10 TO 5 STEP -1
55 FORC=1TO25:CSRB,:LETC$:PRINTCHR96;:D=ASCIKEY:IFD=83;GOSUB98
60 IF D=87;IF MID(1,1)="0";$=$+"0":$=MID(2,7):GOSUB 3
65 IF D=88;IF MID(7,1)="0";$="0"+$:$=MID(1,7):GOSUB 2
70 IF D=65 THEN 72:NEXT C:NEXT B
72 Z(8)=Z(9)
73 IF Z(8)>390;Z(8)=Z(8)-380:GOTO 73
75 Z(9)=Z(9)+4:CSR 5,:DEFM 24:CSR 11:PRINT CHR(Z(8)/10);
78 FOR Z(6)=1 TO 7:Z(7)=ASCIGETC(Z$(A+9),Z(6))/10
80 GOSUB INT Z(7):GOSUB 10*FRAC Z(7):NEXT Z(6):DEFM 9
81 IF C>24;CSR.,:PRINT "Game over",Z(9):GOTO 1
82 Z(6)=C-4
83 FOR E=Z(6) TO C:A=G(E):FOR F=0 TO 6
85 IF FRAC(A/10)=0;DRAWC E,F:GOTO 88
86 DRAW E,F
88 A=INT(A/10):NEXT F:NEXT E:FOR E=1 TO 24
90 IF G(E)=G;FOR F=ETO23:G(F)=G(F+1):NEXTF:Z(6)=E:C=24:GOTO 97
92 NEXT E:GOTO 50
97 Z(9)=Z(9)+7:Z(5)=0:GOTO 83
98 GOSUB 99+A:A=A+1:F=LEN$:E=5-F:$="00"+$+"000":$=MID(1,7)
99 RETURN
100 $="232":RETURN
101 $="72":RETURN
102 $="262":RETURN
103 $="27":A=0:RETURN
104 $="4444":RETURN
105 $="0F":A=4:RETURN
106 $="66":A=6:RETURN
107 $="C6":RETURN
108 $="264":A=7:RETURN
109 $="462":RETURN
110 $="6C":A=9:RETURN
111 $="E2":RETURN
112 $="226":RETURN
113 $="8E":RETURN
114 $="644":A=11:RETURN

The game must be launched in turbo mode (turn on the MK while
holding down '+').

Display view:
 123456789012
!------------!
!#####******$!
!------------!

# - "glass" into which the figures fall; the first column of the
    first segment displays the "bottom" of the glass.
* - the descent zone along which the figure descends before
    falling into the glass. While the figure is ?falling?, it can
    be controlled.
$ - in this segment, after each figure is lowered, a symbol is
    displayed indicating the number of tens of points scored. The
    number can be determined in accordance with the decimal code
    table MK-85, attached to the instruction for the microcomputer.
    Before a new figure appears, the indicator symbol disappears.
    For example: the symbol '{' indicates 70-79 points,
    the symbol '!' - 330-339 points, etc.
    
Controls (if you hold the MK-85 vertically, with the screen facing
you):
     W - figure to the left
     X - figure to the right
     S - rotation of the figure
     A - figure dropping
     
After the figure appears, we have about 5-6 seconds to turn and
select a location before the figure passes the drop zone and
automatically falls into the glass. You cannot control the figure
directly in the glass, because after the descent zone, the figure
immediately appears at the bottom of the glass.
By default, 4 points are given for each dropped figure, and 7
points for each discarded line. The full number of points will be
shown if you lose, after the inscription "Game over".

=====================
From the editor: many thanks to Sergei Bogdanov for this game
(even if he is not the author, still thanks for posting it on his
website sometime in 2000). It?s a pity that there were no
instructions for the game and I had to figure it out based on the
code. Therefore, I tried to describe all the features of Tetris
for the future.
The original TXT document is available on the website:
http://mk.bs0dd.net/