:: Главная bs0dd.net :: Новости :: Гостевая книга ::
:: FAN-сайт Nokia Phones :: Архив Nokia 92xx :: Kannel для Windows ::
-- Switch to English --

Драка!

< Игры Главная

Играть онлайн
Игра находится в программной ячейке 0.

Владельцы телефонов Siemens (а точнее моделей C45 и ME45) наверняка хорошо помнят игру BattleMail.
Это одна из первых сетевых (по SMS) игр для сотовых телефонов. Нужно заранее указать 6 ходов для атаки и защиты, после чего начинается схватка. Каждый игрок имеет 5 жизней, т.е. может выдержать 4 удара и после пятого погибнет. Если в ходе схватки никто не погиб, победителем считается тот, у кого осталось больше жизней. Если этот показатель равен - объявляется ничья. Концепция игры простая, но интересная, однако по причине необходимости поддержки оператором неких "специальных" SMS (если я не ошибаюсь) игра особой популярности не сыскала. Так что большинство людей играло лишь в "тренинг" против компьютера, как и я.

Собственно, данная BASIC игрушка является своеобразным бэкпортом BattleMail для МК85. Правила игры абсолютно те же, бой ведется с "компьютером", выбирающим свои ходы с помощью ГПСЧ.

Как играть:

Перед началом игры нужно задать 6 ходов для атаки (Атк:) и столько же для защиты (Защ:).
Удары и защиту можно ставить на 3 позиции: вверх (голова), вперед (живот) и вниз (ноги).
Направления обозначаются стрелками.

Fight img3

Клавиши:
4 - позиция вверх ↑
5 - позиция вниз ↓
6 - позиция вперед →
DEL - удаление текущей позиции
EXE - подтверждение

После этого на короткое время микрокомпьютер "задумается" (идет генерация ходов компьютера).
Затем на экране отобразятся человечки-соперники и по краям их шкалы здоровья (каждая на 5 ударов).
Начнется бой. Первым всегда ходит игрок. На экране указывается направление (кто бьет) и позиция удара.
Если был нанесен удар, вместо человечка отображается █ и шкала здоровья уменьшается на одну единицу.
Если позиция удара атакующего совпала с позицией защиты противника, значит, что противник поставил блок.
Тогда вместо человечка отображается X и шкала здоровья не уменьшается.
Игра ведется до тех пор, пока кто-то из соперников не погибнет или не кончатся ходы.
Если после 6 ходов никто не погиб, тогда победа присуждается игроку с наибольшим количеством здоровья.
Если количество здоровья одинаково, объявляется ничья.

Игровой код (TXT файл):

1 CSR 11:PRINT " Драка! ";:X=4↑.5
2 Y$="EHLVLHV":T$="4A4V4AH":H$="EVVVVVE":E=94:F=24:G=26:M=5:J=5
3 CSR 0,:PRINT "Атк:";:GOSUB 20:A$=$:PRINT "Защ:";:GOSUB 20:B$=$
4 N$=H$:C$="":D$="":FOR I=0 TO 5:C$=C$+CHR E(RAN#*3)
5 D$=D$+CHR E(RAN#*3):NEXT I:LETC H$:Q$=CHR 96:PRINT Q$;:CSR 11
6 PRINT Q$;:LETC T$:CSR 3:PRINT Q$;:CSR 8:PRINT Q$;:X=2^2:FOR I=1 TO 6
7 U$=GETC (A$,I):CSR 5:PRINT "-";:W$="X":IF U$!=GETC (D$,I);GOSUB 30
8 PRINT U$;:CSR 8:PRINT W$;:X=2^2:CSR 8:PRINT Q$;:LETC N$:CSR 11
9 PRINT Q$;:LETC T$:IF J=0;CSR 8:LETC Y$:PRINT Q$;:X=4^.5:GOTO 40
10 U$=GETC (C$,I):W$="X":CSR 6:PRINT "-";:IF U$!=GETC (B$,I);GOSUB 31
11 IF U$="→";U$="←"
12 CSR 5:PRINT U$;:CSR 3:PRINT W$;:X=2^2:CSR 3
13 PRINT Q$;:LETC H$:CSR 0:PRINT Q$;:LETC T$
14 IF M=0;CSR 3:LETC Y$:PRINT Q$;:X=4^.5:GOTO 41
15 NEXT I:X=4^.5:IF J=M THEN 42:IF J>M THEN 41:GOTO 40
20 P=0:$=""
21 K=ASCI KEY:IF K=0 THEN 21:IF K=8 THEN 24:IF K=4 THEN 23:IF P=6 THEN 21
22 K=K-52:IF K>=0;IF K<=2;P=P+1:$=$+CHR E(K):GOTO 25
23 P=P+1:IF P=7;CSR 0,:RETURN
24 IF P>0;P=P-1:$=MID (1,P)
25 CSR 5,:PRINT $;:GOTO 21
30 W$="█":J=J-1:$=N$:N$=MID (1,5-J)+"H"+MID (7-J,J+1):RETURN
31 W$="█":M=M-1:$=H$:H$=MID (1,5-M)+"H"+MID (7-M,M+1):RETURN
40 $="Победа":GOTO 43
41 $="Увы...":GOTO 43
42 $="Ничья"
43 CSR 0,:CSR 3:PRINT $;

Обозначение != соответствует символу ≠ в МК.
В строке заставки перед словом "Драка!" стоит один пробел и после слова еще три пробела.
Символ █ (он один) соответствует аналогичному символу в МК (режим EXT, комбинация S + Z)
Если игра идет слишком быстро, можно подстроить ее скорость, изменяя "нагрузочное" выражение X=2^2